HELIO SolarSoft Documentation

HELIO SolarSoft Crib Sheets

Below are some notes on how to use the IDL code developed for HELIO. The code is based on SolarSoft and at least the HELIO branch of the SSW tree must be installed in order to use the code.

Sheet No.: 1  –  Introduction

;    Start IDL including HELIO  (other branches can also be included)

setssw helio

;    Within IDL, create the Object that allows you to use HELIO's capabilities

helio = obj_new('hio_setup')


;    Establish the base time interval - this is the overall time period of interest
;    Note: If you have not set a base time, it will ask for one when you try to plot, etc.

helio -> set_basetime					; choose from predefined set of times

times = ['1-jan-2003','15-jan-2003']			; explicitly defined time interval
helio -> set_basetime, timerange=times

helio -> set_basetime, nar=12087			; defined by when AR visible on disk


;    Then you need to define a time timewindow within the base time interval

;    The simplest way is just to set the timewindow to the base time interval

helio -> select_times, /use_basetime			; set timewindow to base time interval

;    The timewindow can also be selected using cursors on a light-curve 
;    Different plot options are shown below - the plots cover the established base time interval
helio -> plot						; GOES X-rays
helio -> plot, /proton					; GOES protons
helio -> plot, /both					; GOES X-rays and protons (two panel)

helio -> plot, /proton, /sta	[/stb]			; STEREO-A or -B protons

helio -> plot, /insitu, /ace				; ACE solar-wind parameters
helio -> plot, /insitu, /sta	[/stb]			; STEREO-A or -B solar-wind parameters

helio -> plot, /des_insitu, /wind			; Use the DES to generate in-situ plots
							; /ACE, /WIND, /ULYSSES, /STA, or /STB

missions = ['stb','goes','sta']
helio -> multi_proton2, times, use=missions		; Three panel plot of energetic protons
;    [/oplot_sep]					; oplot SEP events  [def=goes_proton_event]
;							; oplot_sep=2 asks user to select a list
;    [/oplot_cme]					; oplot CME events  [def=cactus_all]

;    Select the timewindow within the base time interval using cursors

helio -> select_times					; use cursors to select start and end
							; times (using left and right buttons)
							; Does not work for /des_insitu plot

helio -> plot, /zoom					; use timewindow as the new limits of plot
helio -> plot, zoom=[20,60]				; use timewindow w. -/+ delta (mins.)
							; the cursors can be used again if needed
helio -> plot, /apply_zoom				; adjust timewindow by applying zoom values


;    Event lists can be used to identify time periods of interest and set the timewindow
;    There are several ways to load an event list covering the base time interval

helio -> load_eventlist					; Default to the GOES SXR flarelist
list_name = 'goes_proton_event'				; load the specified event list
helio -> load_eventlist, name=list_name

helio -> load_eventlist, /widget			; Select list using a widget
;    [,search_string='xxx']				; filter list description by search string

helio -> load_eventlist, /choose			; Choose list from a table of list titles
;    [,search_string='xxx']				; filter list description by search string
;    [,/flare][,/particle][,/cme][,/swind] 		; <-- filters for list type
;    [,/solar][,/ips][,/geospace][,/planet] 		; <-- filters for list domain

helio -> select_event					; Select an event to define timewindow
;    [,pawidth_min=x] [,xrayclass_min=x]		; minimum values for valid parameters

;    Over-plot selected event (or all) on the light-curveshow, or show details of event

helio -> show_event, /over [,/all]			; over-plots loaded events on current plot
;    [,color=n] 					; 1=red, 2=blu, 3=grn, 4=yell, 5=blk, 6=wht
;    [,xrayclass_min=x]	[nar=1287]			; minimum flare X-ray class or NAR No.
;    [,pawidth_min=x]					; minimum CME PA width

helio -> show_event					; print a brief summry of the event

helio -> show_event, /browser				; display image if one is available
							; (equivalent of -> browser,/show_event)


;    Before you can search for observations, you need to define a set of instruments

;    There are several ways to select the instruments that you are interested in

helio -> select_instruments				; select instruments from a long list
helio -> select_instruments, /widget			; select using widget based on the ICS

inst = ['soho__eit','soho__cds']			; explicitly define list of instruments
helio -> select_instruments, names = inst

helio -> select_instruments, /myfav			; load list of favourites from file

helio -> select_obstype, /halpha			; select by type of observation
							; /magmap, /rhelio, /sep, /structure


;    Use DPAS to search for observations that match time range and instrument selection

helio -> summary, /short				; check on time range and instruments

filelist = helio -> get_filelist()			; return has details of observations & URLs 
							; (some corrections are applied) 
;  If you make a mistake, it is possible to recover the (last??) filelist that was returned. 
;  Note that corrections are not applied by default and have to be explicitly requested.

filelist = helio -> recover_filelist( [/repair] )


;    Examine the list of files that was returned

helio -> summ_filelist, filelist, /plot, /goes		; summary of filelist records 
		[, /make_ack]				; produce Web page of acknowledgements

helio -> plot_filelist, filelist=filelist, /goes	; just plot the data  [or /proton]
;					/data - derive time limits from data  [def is timewindow] 

;    Which files will be retrieved can be modified by applying filters before copying

idx = helio -> select_filelist(filelist, /cad, rate=4)	; cadence of 4/hr  [def. is 1/hr]
							; /force will force new time selection
							; /goes - also plot the GOES light curve 
							; /plot_gongha - separate plot selected times 

helio -> summ_filelist, filelist(idx) [/plot, /goes] 	; summary of selected filelist records 

;    Download the selected results

helio -> download_filelist, filelist(idx) 		; copy the files


;    Select Region of Interest (ROI) on a context image - this could be used to filter UOC records

helio -> show_context					; default to plot of flare locations
helio -> context_cursor, /box


;    Various routines provide context information based on selected time interval

helio -> show_context					; default to plot of flare locations
helio -> show_context,/parker, vel=750,/hee		; plot of the parker spiral

helio -> browser,/show_event				; if URL available in event list
helio -> browser,/solarmonitor				; for selected start date
helio -> browser,/stereo_movie				; 24 hrs STA/STB movie from selected date
helio -> browser,/jmap_ukssdc				; display JMAP for month of selected date
helio -> browser,/flareloc				; Flare locations/active map, selected times

helio -> browser,/current_actitity			; HELIO Current Solar Activity

;    The browser launch routine can be called directly. This route has more options...

date = '1-jul-2007'
hio_launch_browser, date=date, use_url = url		; use supplied URL

hio_launch_browser, date=date, /solarmonitor

hio_launch_browser, date=date, /stereo_movie		; defaults to STB/STA COR2, 24 hours
hio_launch_browser, date=date, stereo_movie=['stb_cor2','stb_cor2']
hio_launch_browser, date=date, stereo_movie=['stb_cor1','sta_cor2']


;    It is possible to display this sheet and other help information in the browser

helio -> browser, /crib					; brings crib sheet up in browser
helio -> browser, /help					; HELIO SSW help pages in browser

helio -> browser, url = myurl				; launches browser with URL provided

;    Display other types of information

helio -> browser, /hec_tabinfo				; show HEC master table in the browser

helio -> save_struct, /hec, /html, /show		; show HEC master table in the browser

R.D. Bentley (UCL-MSSL)

Revised: 26-Mar-2017 21:24

[HELIO logo]